[分享] VB记事本

Private Sub Form_Load()
Me.Left = GetSetting(App.Title, "Settings", "MainLeft", 1000)
Me.Top = GetSetting(App.Title, "Settings", "MainTop", 1000)
Me.Width = GetSetting(App.Title, "Settings", "MainWidth", 5160)
Me.Height = GetSetting(App.Title, "Settings", "MainHeight", 5000)
End Sub


Private Sub Form_Unload(Cancel As Integer)
Dim i As Integer


'close all sub forms
For i = Forms.Count - 1 To 1 Step -1
Unload Forms(i)
Next
If Me.WindowState <> vbMinimized Then
SaveSetting App.Title, "Settings", "MainLeft", Me.Left
SaveSetting App.Title, "Settings", "MainTop", Me.Top
SaveSetting App.Title, "Settings", "MainWidth", Me.Width
SaveSetting App.Title, "Settings", "MainHeight", Me.Height
End If
End Sub


Private Sub tbToolBar_ButtonClick(ByVal Button As MSComCtlLib.Button)
On Error Resume Next
Select Case Button.Key
Case "新建"
mnuFileNew_Click

Case "打开"
mnuFileOpen_Click
Case "保存"
mnuFileSave_Click
Case "打印"
mnuFilePrint_Click
Case "剪切"
mnuEditCut_Click
Case "复制"
mnuEditCopy_Click
Case "粘贴"
mnuEditPaste_Click
Case "粗体"
mnuTxtBold_Click

Case "斜体"
mnuTxtItalic_Click

Case "下划线"
mnuTxtUnderline_Click

Case "左对齐"
mnuTxtL_Click

Case "置中"
mnuTxtC_Click

Case "右对齐"
mnuTxtR_Click

End Select
End Sub

Private Sub mnuHelpAbout_Click()
frmAbout.Show vbModal, Me
End Sub

Private Sub mnuTxtR_Click()
mnuTxtR.Checked = True
mnuTxtL.Checked = False
mnuTxtC.Checked = False
'设置菜单项选中状态
RichTextBox1.SelAlignment = 1
'设置对齐方式为右对齐
End Sub

Private Sub mnuTxtC_Click()
mnuTxtR.Checked = False
mnuTxtL.Checked = False
mnuTxtC.Checked = True
'设置菜单项选中状态
RichTextBox1.SelAlignment = 2
'设置对齐方式为居中
End Sub

Private Sub mnuTxtL_Click()
mnuTxtR.Checked = False
mnuTxtL.Checked = True
mnuTxtC.Checked = False
'设置菜单项选中状态
RichTextBox1.SelAlignment = 0
'设置对齐方式为左对齐
End Sub

Private Sub mnuTxtUnderline_Click()
RichTextBox1.SelUnderline = Not RichTextBox1.SelUnderline
'设置选中字的下划线风格改变
End Sub

Private Sub mnuTxtItalic_Click()
RichTextBox1.SelItalic = Not RichTextBox1.SelItalic
'设置选中字的斜体风格改变
End Sub

Private Sub mnuTxtBold_Click()
RichTextBox1.SelBold = Not RichTextBox1.SelBold
'设置选中字的下粗体风格改变
End Sub

Private Sub mnuTxtColor_Click()
dlgCommonDialog.ShowColor
'显示颜色对话框
RichTextBox1.SelColor = dlgCommonDialog.Color
'将文字颜色设置成选定的颜色
End Sub

Private Sub mnuTxtFont_Click()
dlgCommonDialog.Flags = cdlCFBoth
'设置Flags属性，如果没有这一步，运行是会出现字体不存在错误。
dlgCommonDialog.ShowFont
'根据用户的选择来设置文本属性。
RichTextBox1.SelFontName = dlgCommonDialog.FontName
RichTextBox1.SelFontSize = dlgCommonDialog.FontSize
'设置文字字体和大小。
RichTextBox1.SelBold = dlgCommonDialog.FontBold
RichTextBox1.SelItalic = dlgCommonDialog.FontItalic
RichTextBox1.SelUnderline = dlgCommonDialog.FontUnderline
RichTextBox1.SelStrikeThru = dlgCommonDialog.FontStrikethru
'设置文字风格
End Sub

Private Sub mnuViewStatusBar_Click()
mnuViewStatusBar.Checked = Not mnuViewStatusBar.Checked
sbStatusBar.Visible = mnuViewStatusBar.Checked
End Sub

Private Sub mnuViewToolbar_Click()
mnuViewToolbar.Checked = Not mnuViewToolbar.Checked
tbToolBar.Visible = mnuViewToolbar.Checked
End Sub

Private Sub mnuEditPaste_Click()
RichTextBox1.SelText = Clipboard.GetText()
'将文本从剪贴板粘贴到活动控件
End Sub

Private Sub mnuEditCopy_Click()
Clipboard.SetText RichTextBox1.SelText
'复制选定文本到剪贴板
End Sub

Private Sub mnuEditCut_Click()
Clipboard.SetText RichTextBox1.SelText
'复制选定文本到剪贴板
RichTextBox1.SelText = ""
'删除选定文本
End Sub

Private Sub mnuFileExit_Click()
'卸载窗体
Unload Me

End Sub

Private Sub mnuFilePrint_Click()
dlgCommonDialog.Flags = cdlPDReturnDC + cdlPDNoPageNums
If RichTextBox1.SelLength = 0 Then
dlgCommonDialog.Flags = dlgCommonDialog.Flags + cdlPDAllPages
Else
dlgCommonDialog.Flags = dlgCommonDialog.Flags + cdlPDSelection
End If
dlgCommonDialog.ShowPrinter
' 显示“打印”对话框
RichTextBox1.SelPrint dlgCommonDialog.hDC
'打印
End Sub

Private Sub mnuFileSaveAs_Click()
Dim sFile As String
With dlgCommonDialog
.DialogTitle = "另存为"
.Filter = "所有文件 (*.*)|*.*"
'设置 common dialog 控件的标志和属性
.ShowSave
'弹出打开对话框
If Len(.FileName) = 0 Then
Exit Sub
End If
sFile = .FileName
'把选中的文件名赋给变量sFile
End With
RichTextBox1.SaveFile sFile
'读取文件信息
Caption = sFile
'设置窗口标题
End Sub

Private Sub mnuFileSave_Click()
Dim sFile As String
sFile = Caption
If sFile = "NotePad" Then
'判断是否保存过
mnuFileSaveAs_Click
'调用另存为菜单
Else
RichTextBox1.SaveFile sFile
'保存
End If
End Sub

Private Sub mnuFileOpen_Click()
Dim sFile As String
With dlgCommonDialog
.DialogTitle = "打开"
.Filter = "所有文件 (*.*)|*.*"
'设置 common dialog 控件的标志和属性
.ShowOpen
'弹出打开对话框
If Len(.FileName) = 0 Then
Exit Sub
End If
sFile = .FileName
'把选中的文件名赋给变量sFile
End With

RichTextBox1.LoadFile sFile
'读取文件信息
Caption = sFile
'设置窗口标题
End Sub

Private Sub mnuFileNew_Click()
RichTextBox1.Text = ""
'清空文本框
Caption = "NotePad"
'设置窗口标题
End Sub

Private Sub RichTextBox1_Click()

End Sub