因为在公司用VPN时总的手动切换IP很麻烦，所以用批处理做了一个简单的ip地址切换程序。把需要切换的IP地址、子网掩码和默认网关 输入进去，等需要的时候一双击就可以完成了。很方便,给大家分享一下。希望大家不要笑话呀!
& k! J; |8 l a) W- p
& q) _% g' H" X E2 T/ t更新了一下，刚才有人建议我增加上IP备份。所以我更新了一下，增加了备份和恢复功能。复制内容到剪贴板
代码:
@echo off
mode con cols=84 lines=21
title IP地址设定工具
color 3f
cls
echo.
echo.
echo IP地址更换 for /XP-----By Benteng302
echo -----------------------------------------------------------------
echo [F] 按 F 键更换为办公室IP
echo [U] 按 U 键BHMC IP
echo [S] 按 S 备份IP 设置
echo [R] 按 R 恢复备份 IP （备份位于D:\IP 备份\config.txt,勿删除！)
echo [Q] 按其他任意键退出
echo -----------------------------------------------------------------
echo.
SET Choice=
SET /P Choice= 请选择要进行的操作：
IF /I '%Choice:~0,1%'=='f' GOTO ipset1
IF /I '%Choice:~0,1%'=='u' GOTO ipset2
IF /I '%Choice:~0,1%'=='s' GOTO backup
IF /I '%Choice:~0,1%'=='r' GOTO restore
exit
:ipset1
echo.
echo 正在更换为办公室IP，请稍侯...
netsh interface ip set address name="本地连接" source=static addr=192.168.1.27 mask=255.255.255.0
netsh interface ip set address name="本地连接" gateway=192.168.1.1 gwmetric=0
netsh interface ip set dns name="本地连接" source=static addr=202.106.192.152 register=PRIMARY
netsh interface ip add dns name="本地连接" addr=202.106.192.115 index=2
netsh interface ip set wins name="本地连接" source=static addr=none
echo 感谢使用，按任意键退出...
pause>nul
exit
:ipset2
echo.
echo 正在更换为 BHMC IP，请稍侯...
netsh interface ip set address name="本地连接" source=static addr=10.101.11.28 mask=255.255.255.0
netsh interface ip set address name="本地连接" gateway=10.101.11.1 gwmetric=0
netsh interface ip set dns name="本地连接" source=static addr=10.13.11.19 register=PRIMARY
netsh interface ip add dns name="本地连接" addr=10.31.3.13 index=2
netsh interface ip set wins name="本地连接" source=static addr=none
echo.
echo 感谢使用，按任意键退出...
pause>nul
exit
:backup
echo.
echo 正在备份IP设置，请稍侯...
md D:\IP备份
netsh -c int ip dump>D:\IP备份\config.txt
attrib +h +s D:\IP备份
echo.
echo 备份完毕，按任意键退出...
pause>nul
exit
:restore
echo.
echo 正在还原备份IP，请稍侯...
netsh exec D:\IP备份\config.txt
echo.
echo 还原完毕，按任意键退出...
pause>nul
exit[
本帖最后由 benteng302 于 2007-8-29 14:06 编辑 ]
